;; 1. Based on: Run094
;; 2. Description: VANCO 3C PROP+ADD IIV CL-OBESE  CL-V1 V2-WT LIN CL-WT EXP V2-AGE V1-AGE
;; x1. Author: user

$PROBLEM VANCO 
$INPUT ID	TIME	AMT	RATE	DV	MDV	EVID	GRP	WT	AGE	LOD

$DATA Simulated_data_vancomycin_obese.prn IGNORE=@

$SUBROUTINE ADVAN11 TRANS4
$PK
  TVCL   = THETA(1)*((WT/70)**THETA(10)); TVCL	
  TVV1    = THETA(2)*(1+THETA(11)*(AGE-36.5)); TVV1
  TVQ2	=	THETA(3); TVQ2
 TVV2	=	THETA(4)*((WT/70)**THETA(9))*(1+THETA(11)*(AGE-36.5)); TVV2
  TVQ3 =   THETA(5);TVQ3
  TVV3 = THETA(6);TVV3

;
IF (GRP.EQ.0) THEN
CL = TVCL*EXP(ETA(1)) 
ELSE
CL = TVCL*EXP(ETA(7)) 
ENDIF

V1 = TVV1*EXP(ETA(2)) 
Q2 = TVQ2*EXP(ETA(3))
V2 = TVV2*EXP(ETA(4))
Q3 = TVQ3*EXP(ETA(5))
V3 = TVV3*EXP(ETA(6))
 

  S1   = V1 ; conversion of amount in comp-1 to concentration
;
ET1_0=ETA(1)
ET1_1=ETA(7)
ET2=ETA(2)
ET3=ETA(3)
ET4=ETA(4)
ET5=ETA(5)
ET6=ETA(6)


$THETA
(0, 5.72) ; TVCL
(0, 16.7) ; TVV1
(0, 15.8) ; TVQ2
(0, 6.98) ; TVV2
(0, 5.21) ; TVQ3
(0, 19.5) ; TVV3
(0.0392) ; SD PROPORTIONAL ERR
(1.07) ; SD ADD ERROR
(1) FIX ;
(0, 0.535) ; EXP CL-WT
(-0.054, 0.0136,0.0606) ; SLOPE V1-V2-AGE

$OMEGA 
 0.00278 FIX  ; CL ETA 1_0
 0.187 ; V1 ETA 2
 0 FIX  ; Q2 ETA 3
 0 FIX  ; V2 ETA 4
 0 FIX  ; Q3 ETA 5
 0 FIX  ; V3 ETA 6
 0.0593 ; CL ETA 1_1

$ERROR
TYPE=1
IF(DV.LT.LOD) TYPE = 2

PROP=THETA(7)*F ; proportional part 
ADD=THETA(8) ; additive part 
SD=SQRT(PROP*PROP + ADD*ADD) ; Standard deviation using proportional res error

IPRED = F
DUM = (LOD - IPRED) / SD
CUMD = PHI(DUM)
IF (TYPE .EQ. 1.OR.NPDE_MODE.EQ.1) THEN
 F_FLAG = 0
 Y = IPRED + SD * ERR(1)
ENDIF
IF (TYPE .EQ. 2.AND.NPDE_MODE.EQ.0) THEN
 F_FLAG = 1
 Y = CUMD
 MDVRES=1
ENDIF
IF(TYPE.EQ.2) DV_LOQ=LOD

IRES   = DV - IPRED
IWRES = IRES/SD

$SIGMA 
 1 FIX  ; ERR 1 
;0.1      ; ERR 2

$ESTIMATION METHOD=1 INTER MAXEVAL=0 POSTHOC LAPLACIAN NOABORT NUMERICAL SLOW ; calculation method
;$COVARIANCE MATRIX=S PRINT=E SLOW; standard error of estimate is calculated

$TABLE ID TIME IPRED CWRES NPDE AMT TVCL CL NPDE TVV1 V1 TVQ2 Q2 TVV2 V2 TVQ3 Q3 TVV3 V3 ET1_1 ET1_0 ET2 ET3 ET4 ET5 ET6 MDV EVID	GRP WT	AGE	LOD NOPRINT ONEHEADER FILE=sdtab094_ddmore