$PROBLEM    1
$INPUT      ID                                                                  ;ID
            TIME                                                                ;time
            AMT                                                                 ;Amount
            DV                                                                  ;Dependent variable
            CMT                                                                 ;Compartment
            MDV                                                                 ;Missing data
            EVID                                                                ;Evidence ID
            WT                                                                  ;Body weight
            MUAC                                                                ;Mid-Upper arm circumference
            AGE                                                                 ;Age
            HFA                                                                 ;Height for age z-score
            WFA                                                                 ;Weight for age z-score
            WFH                                                                 ;Weight for height z-score
            BMIFA                                                               ;BMI for age z-score
            MAL                                                                 ;Severe acute malnutrition starus
            ARM                                                                 ;stydy arm
$DATA       Simulated_run1.csv
            IGNORE=@

$SUBROUTINE ADVAN5 TRANS1                                                       ;Specify subroutine
$MODEL      COMP=(1)                                                            ;Absorption compartment
            COMP=(2)                                                            ;Central compartment
            COMP=(3)                                                            ;Peripheral compartment
            COMP=(4)                                                            ;transit compartment 1
            COMP=(5)                                                            ;transit compartment 2
$PK
"FIRST
"COMMON /PRCOMG/ IDUM1,IDUM2,IMAX,IDUM4,IDUM5
"INTEGER IDUM1,IDUM2,IMAX,IDUM4,IDUM5
"IMAX=20000000

  F1MUAC = ( 1 + THETA(10)*(MUAC - 127))                                        ;Linear effect of MUAC on F1
  F1COV=F1MUAC

  AGE50 = THETA(8)
  HILL  = THETA(9)

  OF    = (AGE**HILL)/(AGE50**HILL + AGE**HILL)                                 ;maturation factor based on age
  DELL  = 0.0000001

  TVCL  = THETA(1);                                                             ;Typical value of clearance

  TVCL = TVCL
  CL    = TVCL*EXP(ETA(1))*(OF+DELL)*((WT/9.62)**0.75);                         ;Individual value of clearance

  TVV2  = THETA(2);                                                             ;Typical value of central volume
  V2    = TVV2*EXP(ETA(2))*((WT/9.62)**1.00);                                   ;Individual value of central volume

  TVMT  = THETA(3);                                                             ;Typical value of absorption rate
  MT    = TVMT*EXP(ETA(3));                                                     ;Individual value of absorption rate

  TVF1  = THETA(4)

  SHAP  = THETA(7)                                                              ;Box-cox transformation of F
  PHI   = EXP(ETA(4))                                                           ;Box-cox transformation of F
  ETAATR = (PHI**SHAP - 1)/SHAP                                                 ;Box-cox transformation of F

  TVF1  = TVF1

  TVF1 = F1COV*TVF1
  F1    = TVF1*(EXP(ETAATR));


  TVQ3  = THETA(5)
  Q3    = TVQ3*EXP(ETA(5))*((WT/9.62)**0.75)

  TVV3  = THETA(6)
  V3    = TVV3*EXP(ETA(6))*((WT/9.62)**1.00)

  S2    = V2                                                                    ;Scaling factor in central compartment
                                                                                ;(ng/mL)/1000 = mg/L (dose in mg and DV in ng/mL)
  NN    = 2
  KTR   = (NN+1)/MT

  K14   = KTR
  K45   = KTR
  K52   = KTR

  K20   = CL/V2                                                                 ;Elimination rate constant from central compartment
  K23   = Q3/V2
  K32   = Q3/V3

$ERROR
  IPRED = A(2)/S2                                                          	;Individual prediction
  IF(IPRED.GT.0) IPRED = LOG(A(2)/S2)                                           ;Specify LN-data (only applicable for LN data)

  IF(CMT.EQ.2) THEN
  W = SQRT(SIGMA(1,1))
  Y = IPRED+ERR(1)
  ENDIF

  IRES  = DV-IPRED                                                              ;Individual residual
  IWRES = IRES/W                                                                ;Individual weighted residual

  IF(AMT.GT.0)    DTIM  = TIME
                  TAD   = TIME-DTIM

$THETA  
 (0,2.33627)                                                                    ; 1.TVCL(Typical value clearance)
 (0,109.805)                                                                    ; 2.TVV2(Typical value central volume)
 (0,3.47515)                                                                    ; 3.TVMT(Typical value absorption rate constant)
 1 FIX                                                                          ; 4.Typical value of F1
 (0,1.09593)                                                                    ; 5.Typical value of Q3
 (0,872.467)                                                                    ; 6.Typical value of V3
 (-5,-0.372518,5)                                                               ; Box-Cox shape parameter on F1
 (0.001,2.90527)                                                                ; AGE_50 maturation effect
 1 FIX                                                                          ; HILL factor on maturation effect
$THETA  (-0.024,0.0254265,0.031)                                                ; Mid-upper arm circumference on F1

$OMEGA  
 0  FIX                                                                         ;   1.IIV_CL
 0  FIX                                                                         ;   2.IIV_V2
 1.54726                                                                        ;   3.IIV_KA
 0.342683                                                                       ;   4.IIV_F1
 0.37825                                                                        ;   5.IIV_Q3
 0  FIX                                                                         ;   6.IIV_V3

$SIGMA  0.339105

$ESTIMATION MAXEVAL=0 PRINT=1 POSTHOC METHOD=1 INTER MSFO=msf1
            MCETA=1000 NOABORT

$COVARIANCE PRINT=E MATRIX=R UNCONDITIONAL

$TABLE ID TIME TAD AMT DV AMT CMT MDV EVID CL V2 KTR F1
       ETAS(1:LAST) W IPRED PRED IRES IWRES CWRES NPDE WT MUAC WFA WFH BMIFA MAL
       NOPRINT
       ONEHEADER
       FILE=mytab1.tab