;; 1. Based on: run12
;; 2. Description: EST PACLITAXEL_GEMCITABINE_HUMAN Run=12
;; x1. Author: user
$SIZES LIM6=1000
$PROBLEM PACLITAXEL_GEMCITABINE_HUMAN Run=13
;Kineticist Sonya Tate
;Paclitaxel and gemcitabine: AUC-driven model
$INPUT CCOM,ID,TIME,DV,AMT,CMT,EVID,MDV,GROUP,DOSE0,AUC0,DOSE1,AUC1P,AUC1M

$DATA EST_JHQG_TUMOUR_AUC.csv IGNORE=C
$SUBROUTINE ADVAN6 TOL=3

;Notes: CLARET ET AL 2009 MODEL
;Notes: ABSOLUTE TUMOUR SIZE
;plot diagnostic (PRED,IPRED,CPRED,CPREDI,EPRED)
;plot individual x=(TIME) y=(DV,IPRED,PRED)

$MODEL
;Tumour
COMP=(TUMOUR)

$PK
;Tumour
BASE   = THETA(1)*EXP(ETA(1))
KG     = THETA(2)*EXP(ETA(2))
KD0    = THETA(3)*EXP(ETA(3))
KD1    = THETA(4)*EXP(ETA(4))
LAMBDA = THETA(5)*EXP(ETA(5))

A_0(1)=BASE

$ERROR
IPRED=F
W=F+0.0001
IRES=DV-IPRED
IWRES=IRES/W
Y=F+ERR(1)

$DES
;Tumour
PAC = AUC0
GEM = AUC1P
DADT(1) = KG*A(1) - KD0*EXP(-LAMBDA*T)*PAC*A(1) - KD1*GEM*A(1)

$THETA (0,5)           ;BASE
$THETA (0,0.00001)     ;KG
$THETA (0,0.00001)     ;KD0
$THETA (0,0.0000001)   ;KD1
$THETA (0,0.001)       ;LAMBDA

$OMEGA 0.01            ;BASE
$OMEGA 0.01            ;KG
$OMEGA 0.01            ;KD0
$OMEGA 0.01            ;KD1
$OMEGA 0.01            ;LAMBDA

;Residual error
$SIGMA 0.01            ;ADD

$EST MAXEVAL=9000 PRINT=5 METH=1 INTER

$COV

$TABLE ID TIME DV IPRED IWRES CPRED CWRES CPREDI CWRESI EPRED EWRES BASE KG KD0 KD1 LAMBDA GROUP DOSE0 AUC0 DOSE1 AUC1P AUC1M

FILE=sdtab13 NOPRINT ONEHEADER