$PROB RUN# 2
$INPUT ID C NOMT STD AMT RATE CMT OCC OCCM WEEK TIME DV EVID MDV PACR PAC5 PAC7

$DATA PLACEBO.csv IGNORE=@
;IGNORE=C
IGNORE=(MDV.EQ.1) ; skip administration lines
$PRED
;-------- dropout linked to study design ------------------------------
;to check if ACR=0 at W12 and W14 for studies 27 and 50
STU=0
IF (STD.EQ.27.OR.STD.EQ.50) STU=1
IF (NEWIND.NE.2) PPAC=0
IF (STU.EQ.1.AND.WEEK.EQ.12.AND.DV.EQ.0) PPAC=PPAC+1
IF (STU.EQ.1.AND.WEEK.EQ.14.AND.DV.EQ.0) PPAC=PPAC+1
;flag for records following ACR=0 on both W12 and W14
FLAG=0
IF (WEEK.GE.16.AND.DV.EQ.2.AND.PPAC.EQ.2) FLAG=1
;-------- transitions from score 1 ------------------------------------
PH01=LOG(THETA(1)/(1-THETA(1)))
TM01=THETA(5)
T01=THETA(6)
LGT01=PH01+TM01*((TIME-7)/(T01+(TIME-7)))+ETA(1)
A01=EXP(LGT01)
P01=A01/(1+A01)
PH21=LOG(THETA(3)/(1-THETA(3)))
LGT21=PH21
A21=EXP(LGT21)
P21=A21/(1+A21)
IF (PACR.EQ.1.AND.FLAG.EQ.1) P21=1
IF (PACR.EQ.1.AND.FLAG.EQ.1) P01=0
;-------- transitions from score 0 ------------------------------------
PH10=LOG(THETA(2)/(1-THETA(2)))
TM10=THETA(7)
T10=THETA(8)
LGT10=PH10+TM10*((TIME-7)/(T10+(TIME-7)))+ETA(2)
A10=EXP(LGT10)
P10=A10/(1+A10)
PH20=LOG(THETA(4)/(1-THETA(4)))
LGT20=PH20
A20=EXP(LGT20)
P20=A20/(1+A20)
IF (PACR.EQ.0.AND.FLAG.EQ.1) P20=1
IF (PACR.EQ.0.AND.FLAG.EQ.1) P10=0
;-------- transition's probabilities ---------------------------------
IF (PACR.EQ.1.AND.DV.EQ.0) Y=P01
IF (PACR.EQ.1.AND.DV.EQ.2) Y=P21*(1-P01)
IF (PACR.EQ.1.AND.DV.EQ.1) Y=1-P01-P21*(1-P01)
IF (PACR.EQ.0.AND.DV.EQ.1) Y=P10
IF (PACR.EQ.0.AND.DV.EQ.2) Y=P20*(1-P10)
IF (PACR.EQ.0.AND.DV.EQ.0) Y=1-P10-P20*(1-P10)
;when ACR=0 on both W12 and W14, not use following dropout for estimation
IF (FLAG.EQ.1) Y=1
T01=P01
T21=P21*(1-P01)
T11=1-P01-P21*(1-P01)
T10=P10
T20=P20*(1-P10)
T00=1-P10-P20*(1-P10)
;-------- for output -------------------------------------------------
TRAN=0
IF (PACR.EQ.1.AND.DV.EQ.0) TRAN=01
IF (PACR.EQ.1.AND.DV.EQ.1) TRAN=11
IF (PACR.EQ.1.AND.DV.EQ.2) TRAN=21
IF (PACR.EQ.0.AND.DV.EQ.1) TRAN=10
IF (PACR.EQ.0.AND.DV.EQ.0) TRAN=00
IF (PACR.EQ.0.AND.DV.EQ.2) TRAN=20
$THETA
(0,0.4,1) ; TH1 P01
(0,0.06,1) ; TH2 P10
(0,0.04,1) ; TH3 P21
(0,0.04,1) ; TH4 P20
-4 ; TH5 P01MIN TIME on P01
(0,150) ; TH6 T50 TIME on P01
1.5 ; TH7 P01MIN TIME on P10
(0,25) ; TH8 T50 TIME on P10
$OMEGA
2 ; [A] ETA1 P01
2 ; [A] ETA2 P10
$COV
$ESTIMATION MET=COND LAPLACE LIKE MAX=500 MSFO=P039.msfo
$TABLE STD ID TIME DV EVID TRAN T01 T21 T11 T10 T20 T00
PPAC FLAG WEEK
ONEHEADER NOPRINT FILE=P039.tab