;; 1. Based on: 5b
;; 2. Description: Baseline model with 24h + 12h circadian rhythm + Slope effect model

$PROBLEM Predictive QT project

$INPUT ID DAY DROP TIME AMT CP EVID QT RR QTCF=DV MDV CPP BQTCF DOSE TSFD
; ID        - Grouping variable on individual level
; DAY       - The day the measurements were taken (DAY = 0 for TIME = 0)
; CLOCKTIME - Time of the day given as a time between 00:00 and 23:59
; TIME      - Time since start of study (TIME = 0 is at CLOCKTIME = 00:00 at DAY = 0)
; AMT       - Amount (dose) of drug given in mg
; CP        - Measured drug concentrations in plasma
; EVID      - Event identification data item (0: Observation event; 1: Dose event; 2: Other type of event where the DV data item is ignored)
; QT        - QT interval
; RR        - RR interval - used to correct the QT interval for the heart rate
; QTCF      - QT corrected for heart rate using the Fridericia formula - QTcF is the dependent variable
; MDV       - Missing dependent variable (0: The dependent variable is observed; 1: The dependent variable is missing)
; CPP       - Predicted drug concentration in plasma - Predicted using a separate PK model
; BQTCF     - Baseline value of QTcF - Mean value of the baseline measurements of QTCF
; DOSE      - The dose given - Same as amount but included on all data records
; TSFD      - Time since (first) dose

$DATA Simulated_dataset.csv
   IGNORE = #
   IGNORE = (EVID == 1)

$PRED
;---- Baseline model -----------------------------------------------
   BASE   = THETA(1) * EXP(ETA(1))                       ; Baseline QTcF with between subject varaibility (BSV)

;---- Circadian rhythm ---------------------------------------------
   AMP24  = THETA(2) * EXP(ETA(2))                       ; The amplitude of the 24h circadian rhythm
   SHFT24 = THETA(3) + ETA(3)                            ; The peak shift of the 24h circadian rhythm
   AMP12  = THETA(4) * EXP(ETA(4))                       ; The amplitude of the 12h circadian rhythm
   SHFT12 = THETA(5) + ETA(5)                            ; The peak shift of the 12h circadian rhythm

   CIRC24 = AMP24 * COS(2 * 3.14 * (TIME - SHFT24)/24)   ; 24 hour circadian rhythm
   CIRC12 = AMP12 * COS(2 * 3.14 * (TIME - SHFT12)/12)   ; 12 hour circadian rhythm

   RYTM   = BASE * (1 + CIRC24 + CIRC12)                 ; Change in baseline QTcF over the day due to circadian rhythm

;---- Effect model -------------------------------------------------
   SLOPE  = THETA(6) + ETA(6)                            ; Linear effect
   EFF    = SLOPE * CPP                                  ; Linear effect

;---- Error Model --------------------------------------------------
   IPRED  = RYTM  + EFF                                  ; Linear direct effect model
   W      = IPRED * SIGMA(1,1)
   IWRES  = (QTCF - IPRED)/W

   Y      = IPRED + IPRED*EPS(1)

;---- Initial estimates --------------------------------------------
$THETA (0, 372.6)                                        ; 1 Baseline QTcF [ms]
$THETA (0, 0.01844)                                      ; 2 Amplitude  24h
$THETA (0, 3.62)                                         ; 3 Peak shift 24h
$THETA (0, 0.01392)                                      ; 4 Amplitude  12h circadian rhythm
$THETA (0, 1.301)                                        ; 5 Peak shift 12h circadian rhythm
$THETA (0, 0.003441)                                     ; 6 Slope (linear effect) parameter

$OMEGA  0.0392                                           ; 1 Baseline QTcF - (BSV)
$OMEGA  0.3523                                           ; 2 Amplitude 24h  - BSV
$OMEGA  2.007                                            ; 3 Peak shift 24h - BSV
$OMEGA  0.3848                                           ; 4 Amplitude 12h  - BSV
$OMEGA  0.993                                            ; 5 Peak shift 12h - BSV
$OMEGA  0.0001                                           ; 6 Slope          - BSV

$SIGMA  0.01802                                          ; 1 Proportional residual error [ms]

$ESTIMATION METHOD=1 MAXEVALS=99999 INTER NOABORT PRINT=5

$COVARIANCE

$TABLE ID TIME DV PRED IPRED WRES IWRES CWRES CWRESI CIWRESI           NOPRINT ONEHEADER FILE=sdtab7b
$TABLE ID TIME DV BASE AMP24 SHFT24 AMP12 SHFT12 SLOPE ETAS(1:6)       NOPRINT ONEHEADER FILE=patab7b
$TABLE ID TIME DV AMT CP EVID QT RR MDV CPP BQTCF DOSE TSFD RYTM       NOPRINT ONEHEADER FILE=mytab7b