$PROBLEM    Midazolam PK in morbidly obese patients and healthy
;           volunteers
$INPUT      ID TIME AMT RATE DV CMT MDV OBES TBW
$DATA       Simulated_data_MDZ.csv IGNORE=@
$SUBROUTINE ADVAN6 TOL=5
$MODEL      COMP=(PODOSE) COMP=(CENTRAL) COMP=(PERIP) COMP=(PERIP2)
            COMP=(TRANSIT1) COMP=(TRANSIT2) COMP=(TRANSIT3)
$PK 
TVCL= THETA(1)
CL= TVCL*EXP(ETA(1))     	; midazolam CL in L/min

IF(OBES.EQ.0) TVF1= THETA(2)
IF(OBES.EQ.1) TVF1= THETA(10)
F1= TVF1*EXP(ETA(2))	        ; bioavailabilty

TVV2= THETA(3)*(1+THETA(8)*(TBW-127))
V2= TVV2*EXP(ETA(5))            ; volume (L)

TVQ= THETA(4)
Q= TVQ*EXP(ETA(3))              ; CL to peripheral compartment (L/min)

TVV3= THETA(5)*(TBW/127)**THETA(9)
V3= TVV3*EXP(ETA(6))            ; volume perif. compartment (L)

IF(OBES.EQ.0) TVKA= THETA(6)
IF(OBES.EQ.1) TVKA= THETA(6)*THETA(11)
KA= TVKA*EXP(ETA(4))	        ; min-1

KTR= KA
V4= V3                    ; 2nd periph volume compartment (L)
Q4= THETA(7)              ; CL to 2nd peripheral comp (L/min)
;
S2=V2                            
S3=V3
;
K15=KA
K56=KTR
K67=KTR
K72=KTR
K20=CL/V2
K23=Q/V2
K32=Q/V3
K24=Q4/V2
K42=Q4/V4

$DES 
DADT(1)= -K15*A(1)
DADT(2)=                                KTR*A(7) -K23*A(2) +K32*A(3) -K24*A(2) +K42*A(4) -K20*A(2)
DADT(3)=                                          K23*A(2) -K32*A(3)
DADT(4)=                                                              K24*A(2) -K42*A(4)
DADT(5)=  K15*A(1) -KTR*A(5)
DADT(6)=            KTR*A(5) -KTR*A(6)
DADT(7)=                      KTR*A(6) -KTR*A(7)

$ERROR 
COM1=0
IF (OBES.EQ.0) COM1=1
COM2=0
IF (OBES.EQ.1) COM2=1
;
IPRED=F                       ; individual prediction
;
Y1=IPRED*(1+ERR(1))           ; healthy volunteers (HV)
Y2=IPRED*(1+ERR(2))           ; morbidly obese (MO)
;
Y=Y1*COM1+Y2*COM2
;
IRES=DV-IPRED                ; individual residual
DEL=0
IF(IPRED.EQ.0)DEL=1
IWRES=(1-DEL)*IRES/(IPRED+DEL)
$THETA  (0,0.358884) ; CL (L/min)
 (0,0.284478) ; F1 healthy volunteers
 (0,44.1387) ; V2 (L)
 (0,1.32531) ; Q (L/min)
 (0,138.516) ; V3 (L)
 (0,0.130108) ; KA healthy volunteers
 (0,0.149851) ; Q4
 (0,0.0105014) ; TBW power V2
 (0,3.05864) ; TBW power V3
 (0,0.603158) ; F1 MO
 (0,0.441406) ; frac KA MO
$OMEGA  0.0321446  ;         CL
 0.067436  ;         F1
 0  FIX  ;          Q
 0.155626  ;         KA
$OMEGA  BLOCK(2)
 0.266402  ;         V2
 0.120077 0.111963  ;         V3
;
$SIGMA  0.0100397
 0.218069
       ; residuele (error/epsilon)
$ESTIMATION SIGDIG=3 MAXEVAL=0 PRINT=5 NOABORT METHOD=1 INTERACTION
            POSTHOC
;$COVARIANCE COMP
$TABLE ID TIME AMT RATE DV CMT MDV OBES TBW IPRED IWRES CWRES CMT
NOPRINT ONEHEADER FILE=sdtab
$TABLE ID TIME AMT RATE DV CMT MDV OBES TBW ETA(1) ETA(2) ETA(3) ETA(4) ETA(5)
ETA(6) NOPRINT NOAPPEND ONEHEADER FILE=patab
$TABLE ID TIME AMT RATE DV CMT MDV OBES TBW NOPRINT NOAPPEND
ONEHEADER FILE=cotab