;; 1. Based on: 164
;; 2. Description: 
;;    Linear relationship for CRCL on CLR
;; 3. Label:
;;    Basic model
;; 4. Structural model:
;;    Parent: Two compartment linear model, with transit absorption compartment
;;    Metabolite: One compartment model with first order formation
;; 5. Covariate model:
;;    Parent: CRCL on CLR, all WT on CLN, V2, Q, V3
;;    Metabolite: all WT on CLM, VM
;; 6. Inter-individual variability:
;;    Parent: CLn, CLr, V2, V3, BIO(F1), MTT, NN
;;    Metabolite: VM, CLM BLOCK(2)
;; 7. Inter-occasion variability:
;; 8. Residual variability:
;;    Non-transformed data
;;    Edoxaban plasma and urine: Proportional
;;    M4: Proportional
;;    Correlation plasma errors
;; 9. Estimation:
;;    FOCE INTER
$PROBLEM    Study 120
$INPUT      STUD ID AGE SEX RACE ETH SCR CRCL BMI HT WT CMT OAMT=DROP
            EVID DTIM=DROP STIM=DROP ETIM=DROP UVOL ODV=DROP NTIM=DROP
            TIME URIN CORR=DROP PER=DROP TRT=DROP OBLQ=DROP ID2=DROP
            DV2=DROP BLQ REF GRP ODVM=DROP DV AMT L2
$DATA       Simulated_data.csv
            IGNORE=@ IGNORE=(BLQ.GT.0) IGNORE=(CRCL.EQ.0)
 ;ESRD

;CMT 1=dose, 2=edox obs, 4=M4 obs, -5/5=edox urine
$SUBROUTINE ADVAN13 TOL=6
$MODEL      COMP=(DEPOT DEFDOSE) COMP=(EDOCP) COMP=(EDOPER) COMP=(MET)
            COMP=(EDOCU)
$PK  
"FIRST
"        COMMON/PRCOMG/   IDUM1,IDUM2,IMAX,IDUM4,IDUM5
"INTEGER IDUM1, IDUM2, IMAX, IDUM4, IDUM5
"IMAX=10000000

    IF(AMT.GT.0) PODO=AMT
    IF(AMT.GT.0) TDOS=TIME

    CLWT  = (WT/70)**THETA(5)
    CREA  = (140 - AGE)*WT/(72*SCR)                  ;male
    IF(SEX.EQ.2) CREA = 0.85*(140 - AGE)*WT/(72*SCR) ;female
    CLCRCL= THETA(7)*CRCL

    VWT   = (WT/70)**THETA(6)

    TVCLN = THETA(1)*CLWT
    TVCLR = CLCRCL
    TVCL  = TVCLN + TVCLR
    TVV2  = THETA(2)*VWT
    TVV3  = THETA(3)*VWT
    TVQ3  = THETA(4)*CLWT
    TVF1  = THETA(8)
    TVMTT = THETA(9)
    TVNN  = THETA(10)

    CLN   = TVCLN*EXP(ETA(1))
    CLR   = TVCLR*EXP(ETA(4))
    CL    = CLN + CLR
    V2    = TVV2*EXP(ETA(2))
    V3    = TVV3*EXP(ETA(3))
    Q     = TVQ3
    MTT   = TVMTT*EXP(ETA(6))
    NN    = TVNN*EXP(ETA(7))
    KTR   = (NN+1)/MTT
    F1    = 0
    PSI   = LOG(TVF1/(1 - TVF1))
    VF1   = EXP(PSI + ETA(5))
    BIO   = VF1/(1 + VF1)
    
;;M4    
    TVVM  = THETA(11)*VWT
    TVCLM = THETA(12)*CLWT
    V4    = TVVM*EXP(ETA(8))
    CLM   = TVCLM*EXP(ETA(9))

;Microconstant and scaling
    S2    = V2                ; Dose in nanog, DV in nanomol/L --> V in L
    K12    = KTR
    K24    = CLN/V2
;    K20    = CLN/V2
    K23    = Q/V2 
    K32    = Q/V3
    S4     = V4
    K40    = CLM/V4
    S5     = UVOL ;  UVOL is urine volume in L, uirine conc i nM
    K25    = CLR/V2

    FE     = CLR/CL
    FM     = CLN/CL

;    LNFAC = LOG(2.5066)+(NN+.5)*LOG(NN)-NN
    LNFAC = LOG(2.5066)+(NN+.5)*LOG(NN)-NN+LOG(1+1/(12*NN))

$DES 
    X = .00001
    IF(T.GT.TDOS) THEN
    DADT(1) = EXP(LOG(BIO*PODO+X)+LOG(KTR+X)+NN*LOG(KTR*(T-TDOS)+X)-KTR*(T-TDOS)-LNFAC)-K12*A(1)
    ELSE
    DADT(1) = EXP(LOG(BIO*PODO+X)+LOG(KTR+X)+NN*LOG(KTR*T+X)-KTR*T-LNFAC)-K12*A(1)
    ENDIF

    DADT(2) = K12*A(1)- K24*A(2) - K23*A(2) + K32*A(3) - K25*A(2)
    DADT(3) = K23*A(2) - K32*A(3)
    DADT(4) = K24*A(2) - K40*A(4)
    DADT(5) = K25*A(2)

$ERROR  (ONLY OBSERVATION) 
    IPRED = F
    IRES  = DV - F
    WP    = IPRED
    WA    = 1
    IF(WP.EQ.0) WP = 1
    IWRES = IRES/WP

    Y     = IPRED + WP*EPS(1) + WA*EPS(4)
    IF(CMT.EQ.4) Y     = IPRED + WP*EPS(2) + WA*EPS(5)
    IF(CMT.EQ.5) Y     = IPRED + WP*EPS(3) + WA*EPS(6)

$THETA  (0,10.1101) ; 1CL; L/h
$THETA  (0,95.4174) ; 2V2; L
$THETA  (0,54.2792) ; 3V3; L
$THETA  (0,5.19333) ; 4Q; L/h
$THETA  0.75 FIX ; 5ALLCL
$THETA  1 FIX ; 6ALLV
$THETA  (0,0.108951) ; 7CLCRCL
$THETA  (0,0.722853,1) ; 8F1
$THETA  (0,0.731213) ; 9MTT
$THETA  8.07871 FIX ; 10NN
$THETA  (0,78.0995) ; 11VM
$THETA  (0,113.094) ; 12CLM
$OMEGA  0.0312053  ;     IIV_CL  ;          1
$OMEGA  0.0274019  ;     IIV_V2  ;          2
$OMEGA  0.123073  ;     IIV_V3  ;          3
$OMEGA  0.0736616  ;    IIV_CLR  ;          4
$OMEGA  0.417822  ;     IIV_F1  ;          5
$OMEGA  0.282771  ;    IIV_MTT  ;          6
$OMEGA  1.50033  FIX  ;     IIV_NN  ;          7
$OMEGA  BLOCK(2)
 0.247968  ;     IIV_VM  ;          8
 0.179348 0.180483  ;  IIV_CLMNN  ;          9
; 0.0662219 0.0523736 0.0543895  ; IIV_CLr    ;         10
$SIGMA  BLOCK(2)
 0.0236663  ;  1Prop err
 0.00656144 0.0337085  ; 2MProp err
;BLOCK(2)
$SIGMA  0.0646141  ; 3UProp err
$SIGMA  0  FIX  ;   4Add err
$SIGMA  0  FIX  ;  5MAdd err
$SIGMA  0  FIX  ;  6UAdd err
$ESTIMATION METHOD=1 INTER MAX=0 NOABORT PRINT=3
;$NONP UNCONDITIONAL
;$COVARIANCE MATRIX=S PRINT=E
;$TABLE      ID TIME CMT IPRED IWRES CWRES NOPRINT ONEHEADER
;            FILE=sdtab164
;$TABLE      ID AGE WT BMI HT SCR CRCL CREA NOPRINT ONEHEADER
;            FILE=cotab164
;$TABLE      ID SEX RACE ETH GRP NOPRINT ONEHEADER FILE=catab164
;$TABLE      ID FE FM CL CLN CLR CLM V2 V3 V4 MTT NN BIO ETA1 ETA2 ETA3
;            ETA4 ETA5 ETA6 ETA7 ETA8 ETA9 NOPRINT ONEHEADER
;            FILE=patab164