;; 1. Based on: 40b_new
$PROBLEM    METABOLITE 1 GLIBENCLAMIDE PK ANALYSIS
;check - cp run39.mod, cov

;estimated number of TC, log transformation
$INPUT      ID EXPR AMT TIME CONC=DV EFFD EFFP EFFR CMT EVID
$DATA      Simulated_GB_PK1.csv IGNORE=@
$SUBROUTINE ADVAN6 TOL5
$MODEL      COMP=(ABS) COMP=(CENT) COMP=(PERIPH)
$PK 
"FIRST
"      COMMON/PRCOMG/ IDUM1,IDUM2,IMAX,IDUM4,IDUM5
"INTEGER IDUM1,IDUM2,IMAX,IDUM4,IDUM5
"IMAX=5000000

IF(AMT.GT.0.AND.CMT.EQ.1)PODO=AMT
IF(AMT.GT.0.AND.CMT.EQ.2)PODO=0
IV=0
PO=0
IF(EXPR.EQ.3) IV=1
IF(EXPR.EQ.4) PO=1
K    =THETA(1)*EXP(ETA(1))
K23  =THETA(2)*EXP(ETA(2))
K32  =THETA(3)*EXP(ETA(3))
V2   =THETA(4)*EXP(ETA(4))
F1   =0
F2   =1000
KA   =THETA(5)*EXP(ETA(5))
BIO  =1000*THETA(6)*EXP(ETA(6))
MTT  =THETA(7)*EXP(ETA(7))
NN   =THETA(8)*EXP(ETA(8))
KTR  =(NN+1)/MTT
;NFAC =SQRT(2*3.1415)*NN**(NN+0.5)*EXP(-NN)
LNFAC=LOG(2.5066)+(NN+0.5)*LOG(NN)-NN
S2=V2
$DES 
X=KTR*T
;DADT(1)=BIO*PODO*KTR*(KTR*T)**NN*EXP(-KTR*T)/NFAC-KA*A(1)
DADT(1)=EXP(LOG(BIO*PODO+.00001)+LOG(KTR)+NN*LOG(X+.00001)-X-LNFAC)-KA*A(1)
DADT(2)=KA*A(1)-K*A(2)-K23*A(2)+K32*A(3)
DADT(3)=K23*A(2)-K32*A(3)
$ERROR 
IPRED=F
W=SQRT(THETA(9)**2+THETA(10)**2*F**2)*(1+PO*THETA(11))
IRES=DV-IPRED
IWRES=IRES/W
Y=IPRED+ERR(1)*W*(1+PO*THETA(11))
$THETA  (0,1.14) ; K
$THETA  (0,0.363) ; K23
$THETA  (0,0.691) ; K32
$THETA  (0,3.79) ; V2
$THETA  (0,0.652) ; KA
$THETA  (0,0.959) ; BIO
$THETA  (0,0.458) ; MTT
$THETA  (0,22.9) ; NN
$THETA  .15 FIX ; ADD_ERROR
$THETA  (0,0.0826) ; PROP_ERROR
$THETA  (0,0.278) ; ERROR
$OMEGA  0.0135 ; K
$OMEGA 0  FIX ; K23
$OMEGA 0.0306 ; K32
$OMEGA 0.0214 ; V2
$OMEGA 0.571 ; KA
$OMEGA 0.0642 ; BIO
$OMEGA 0.0916 ; MTT
$OMEGA 0.797 ; NN
$SIGMA  1  FIX ; EPS
$ESTIMATION MAXEVALS=0 PRINT=2 POSTHOC NOABORT MSFO=msfb40b METH=1
            INTER
;$COV

;$TAB ID TIME IPRED IWRES  ONEHEADER NOPRINT FILE=sdtab40b

;$TAB ID EXPR TIME IPRED IWRES ONEHEADER NOPRINT FILE=mutab40b

;$TAB ID K K23 K32 V2 BIO KA MTT NN ONEHEADER NOPRINT FILE=patab40b