; Model desc: 3STUDIES - ALLOMETRIC SCALING FIXED FFM/53 kg
; Ref. model: 039A
; Duplicated from: 034E
; Duplicated from: 034C
; Duplicated from: 034B
; Duplicated from: 034A
; Duplicated from: 034
; Duplicated from: 032
; Duplicated from: 004H
; Duplicated from: 004G
$PROBLEM    miltefosine PK analyse
$INPUT      C ID ZIS TIME DV AMT ADDL II WT CMT MDV HT GRP SEX
$DATA      simulated_nm_miltefosine_v28.csv IGNORE=C
$SUBROUTINE ADVAN4 TRANS4
$PK 
IF (GRP.EQ.1) FLA1=1  ;GRP = 1, European Adults
IF (GRP.EQ.1) FLA2=0 
IF (GRP.EQ.1) FLA3=0   

IF (GRP.EQ.2) FLA1=0  ;GRP = 2, Indian Pediatric - 1.5 mg/kg (Sundar, 2003)
IF (GRP.EQ.2) FLA2=1 
IF (GRP.EQ.2) FLA3=0
IF (GRP.EQ.3) FLA1=0  ;GRP = 3, Indian Pediatric - 2.5 mg/kg (Sundar,2003)
IF (GRP.EQ.3) FLA2=1
IF (GRP.EQ.3) FLA3=0

IF (GRP.GE.4) FLA1=0  ;GRP = 4, Indian Adult - 50 mg 6 weeks (Jha, 1999)
IF (GRP.GE.4) FLA2=0
IF (GRP.GE.4) FLA3=1

IF (GRP.GE.5) FLA1=0  ;GRP = 5, Indian Adult - 50 mg 1 week + 100 mg 3 weeks (Jha, 1999)
IF (GRP.GE.5) FLA2=0
IF (GRP.GE.5) FLA3=1

IF (GRP.GE.6) FLA1=0  ;GRP = 6, Indian Adult - 100 mg 4 weeks (Jha, 1999)
IF (GRP.GE.6) FLA2=0
IF (GRP.GE.6) FLA3=1

IF (GRP.GE.7) FLA1=0  ;GRP = 7, Indian Adult - 100 mg 1 week + 150 mg 3 weeks (Jha, 1999)
IF (GRP.GE.7) FLA2=0
IF (GRP.GE.7) FLA3=1

;Body composition
;Janmahasatian S, Duffull SB, Ash S, Ward LC, Byrne NM, Green B.
;Quantification of lean bodyweight. Clin Pharmacokinet. 2005; 44(10): 1051–65.

IF (SEX.EQ.0) THEN; female
WHSMAX=37.99
WHS50=35.98
ELSE; male
WHSMAX=42.92
WHS50=30.93
ENDIF

IF (HT.GT.0) THEN
HTM=HT/100; cm->m
FFM=WHSMAX*HTM**2*WT/(WHS50*HTM**2+WT)
ELSE; Height missing
FFM=0.9*WT ; assume FFM is 90% of WT (typical in GFR data set)
ENDIF


TVCL=THETA(1)*(FFM/53)**0.75	; Normalized to 53 kg FFM (median Indian dataset), FIXED EXPONENT
CL=TVCL*EXP(ETA(1))

TVV2=THETA(2)*(FFM/53)**1.00	; FIXED EXPONENT
V2=TVV2*EXP(ETA(2))

TVQ=THETA(3)
Q=TVQ*EXP(ETA(3))

TVV3=THETA(4)
V3=TVV3*EXP(ETA(4))

TVKA=THETA(5)
KA=TVKA*EXP(ETA(5))

S2=V2
S3=V3
K=CL/V2
K23=Q/V2
K32=Q/V3
KA=KA

SUM=K23+K32+K
TER1=SQRT(SUM**2-4*K32*K)
LAB1=0.5*(SUM+TER1)
T12A=LOG(2)/LAB1
LAB2=0.5*(SUM-TER1)
T12B=LOG(2)/LAB2

$ERROR 
IPRED=F
IRES=DV-IPRED
TY=F
IF(TY.LT.0.001) TY=0.001
W=SQRT(THETA(6)**2+TY*TY*THETA(7)**2)
IF (W.LT.0.001) W=0.001
IWRES=IRES/W
IF(F.LT.0.001) TY=0.001
Y=TY+THETA(6)*EPS(1)+TY*((FLA1*THETA(7)*EPS(2))+(FLA2*THETA(8)*EPS(2))+(FLA3*THETA(9)*EPS(2)))

$THETA  
 (0,4.03333) 			; CL
 (0,40.8631) 			; V2
 (0,0.0344937) 			; Q
 (0,1.75404) 			; V3
 (0,9.61217) 			; KA 
  0 FIX 			; Add Error
 (0,0.349007) 			; Prop Error EUR ADULT
 (0,0.539726) 			; Prop Error IND PAED
 (0,0.349915) 			; Prop Error IND ADULT

$OMEGA  BLOCK(2)
 0.101006  			; ETA CL
 0.0988503 0.115167  		; ETA V2

 $OMEGA  
0  FIX  			; ETA Q
0  FIX  			; ETA V3
0.0335375  			; ETA KA

$SIGMA  
1  FIX
1  FIX

$ESTIMATION MAXEVAL=0 NOABORT PRINT=5 METHOD=1 INTER POSTHOC
            MSFO=MSF0039E
;$COVARIANCE PRINT=E
$TABLE      NOPRINT ONEHEADER FILE=SDTAB039E ID TIME IPRED IRES IWRES
$TABLE      NOPRINT ONEHEADER FILE=PATAB039E ID CL ETA(1) V2 ETA(2) Q
            ETA(3) V3 ETA(4) T12A T12B
$TABLE      NOPRINT ONEHEADER FILE=0039E.TAB ID TIME DV AMT ADDL II
            IPRED IRES IWRES KA ETA(5) CL ETA(1) V2 ETA(2) Q ETA(3) V3
            ETA(4) T12A T12B WT HT GRP SEX
$TABLE      NOPRINT ONEHEADER FILE=0039E_DEMO.TAB ID HT WT FFM SEX GRP