$PROB   ART9 IOV GRP LNDV  
;; as run20, Q=0.63*WT
$DATA   Simulated_LNno0135x.csu IGNORE=#
$INPUT  ID GRP OCC AGE WT HT CIG DAT2=DROP TIME AMT DV CMT  
$SUBROUTINE ADVAN6 TRANS1 TOL=5
$MODEL NCOMP=5 
       COMP=(GUT DEFDOSE)
       COMP=LIVER 
       COMP=(SALIVA DEFOBS)
       COMP=ENZPOOL
       COMP=PREC

$PK
"FIRST
" COMMON /PRCOMG/ IDUM1,IDUM2,IMAX,IDUM4,IDUM5
" INTEGER IDUM1,IDUM2,IMAX,IDUM4,IDUM5
" IMAX=10000000
       OCC1 = 0
       OCC2 = 0
       OCC3 = 0
       OCC4 = 0
       OCC5 = 0
       OCC6 = 0
       IF(OCC.EQ.1)OCC1=1
       IF(OCC.EQ.2)OCC2=1
       IF(OCC.EQ.3)OCC3=1
       IF(OCC.EQ.4)OCC4=1
       IF(OCC.EQ.5)OCC5=1
       IF(OCC.EQ.6)OCC6=1
       TEN   = THETA(1)
       KEN   = 0.693/TEN
       SIND  = THETA(2)            ;slope for enzyme induction
       CLINT = THETA(3)*EXP(ETA(1))
       BFL   = 0.63*WT                  ;l/h for 55kg
       VS    = THETA(4)*EXP(ETA(2))
     ;......IOV.........
       IOV1  =ETA(3)*OCC1+ETA(4)*OCC2+ETA(5)*OCC3
       IOV2  =ETA(6)*OCC4+ETA(7)*OCC5+ETA(8)*OCC6+IOV1
       IOV3  =ETA(9)*OCC1+ETA(10)*OCC2+ETA(11)*OCC3
       IOV4  =ETA(12)*OCC4+ETA(13)*OCC5+ETA(14)*OCC6+IOV3  
       ALAG1 = THETA(5)*EXP(IOV2)
       KA    = THETA(6)*EXP(IOV4)
       FU    = 0.14
       KM    = THETA(7)

       VL    = 1
       TPEN  = THETA(8)
       KPEN  = 1/TPEN
       S3    = VS/FU
       BASENZ= 1
       BASEPR= KEN/KPEN
       F4    = BASENZ
       F5    = BASEPR
       
$DES
       BOX     = CLINT*A(4)*KM/(A(2)+KM)
       E       = FU*BOX/(BFL+FU*BOX)
       BAV     = 1-E
       CLH     = BFL*E
       DADT(1) = -KA*A(1)
       KS0     = BFL/VS
       DADT(2) = KA*A(1)-BFL*BAV*A(2)/VL+KS0*A(3)-BFL*E*A(2)/VL
       DADT(3) = BFL*BAV*A(2)/VL-KS0*A(3)
       DADT(4) = KPEN*A(5)-KEN*A(4)
       DADT(5) = KEN*(1+SIND*A(2))-KPEN*A(5)
       
$ERROR
        IPRED= LOG(1)
        IF (F.GT.0) IPRED=LOG(F)
        W     = 1
        IRES  = DV-IPRED
        IWRES = IRES/W
        Y     = IPRED + W * EPS(1)
       

$THETA  (0, 37.9)            ;TEN
$THETA  (0,0.0179)           ;SIND
$THETA  (0,2880)             ;CLINT
$THETA  (0,48.8)             ;VS
$THETA  (0.5 FIX)            ;ALAG1
$THETA  (0.1,0.184,2)        ;KA
$THETA  (1,1370,100000)      ;FU
$THETA  (0,1.86)             ;TPEN

$OMEGA  0.106                ;CLINT
$OMEGA  0 FIXED              ;VS
$OMEGA  BLOCK(1) 6.06        ;IOV_ALAG1 
$OMEGA  BLOCK(1) SAME        ;IOV_ALAG1 
$OMEGA  BLOCK(1) SAME        ;IOV_ALAG1 
$OMEGA  BLOCK(1) SAME        ;IOV_ALAG1 
$OMEGA  BLOCK(1) SAME        ;IOV_ALAG1 
$OMEGA  BLOCK(1) SAME        ;IOV_ALAG1 
$OMEGA  BLOCK(1) 0.307       ;IOV_KA
$OMEGA  BLOCK(1) SAME        ;IOV_KA
$OMEGA  BLOCK(1) SAME        ;IOV_KA
$OMEGA  BLOCK(1) SAME        ;IOV_KA
$OMEGA  BLOCK(1) SAME        ;IOV_KA
$OMEGA  BLOCK(1) SAME        ;IOV_KA

$SIGMA 0.253                 ;RUV_ADD

;$ESTIMATION NOABORT POSTHOC MAXEVAL=9999 PRINT=3 MSFO=msfb55
$ESTIMATION MAXEVAL=0
;$COVARIANCE PRINT=E
$TABLE ID TIME IPRED IWRES                   NOPRINT ONEHEADER FILE=sdtab55
$TABLE ID E CLH VS KA ALAG1 ETA1 ETA3 ETA5 ETA6 ETA7 ETA8 ETA9 ETA10 
NOPRINT ONEHEADER FILE=patab55
$TABLE AGE WT HT CIG                         NOPRINT ONEHEADER FILE=cotab55
$TABLE GRP OCC                               NOPRINT ONEHEADER FILE=catab55
$TABLE ID TIME E IPRED                       NOPRINT ONEHEADER FILE=mytab55