$PROB FUROSEMID
;FOCE INERACTIon transit compartment model
$INPUT ID TIME AMT PREP ODV DV SEX AGE WT SS II NYHA SCR DROP DROP DROP MDV
$DATA furosemide_pk_simulated.csv IGNORE=#
$SUBROUTINES ADVAN6 TOL5
$MODEL NCOMP=2 COMP(ABS DEFDOSE)
               COMP=(CENTRAL DEFOBS)
$PK
;IF(AMT.GT.0.AND.CMT.EQ.1)PODO=AMT
;IF(AMT.GT.0.AND.CMT.EQ.2)PODO=0
IF(AMT.GT.0)PODO=AMT
CLCRM=1.24*(140-AGE)*WT/SCR
CLCRF=1.04*(140-AGE)*WT/SCR
CLCR =CLCRM*SEX+CLCRF*(1-SEX)
TVCL =THETA(1)*(1+THETA(4)*(CLCR-60))
CL   =TVCL
V    =THETA(2)
K  =CL/V
TVKA =THETA(3)*(1+(1-PREP)*(K+THETA(5)))
KA=TVKA*EXP(ETA(1))
K12  =KA
BIO  =1000 *EXP(ETA(2))
F1   =0
S2=V
MTT  =THETA(6)*EXP(ETA(3))
NN   =THETA(7)*EXP(ETA(4))
KTR  =(NN+1)/MTT
;NFAC =SQRT(2*3.1415)*NN**(NN+.5)*EXP(-NN)
LNFAC=LOG(2.5066)+(NN+.5)*LOG(NN)-NN
$DES
X=KTR*T
;DADT(1)=BIO*PODO*KTR*(KTR*T)**NN*EXP(-KTR*T)/NFAC-KA*A(1)
DADT(1)=EXP(LOG(BIO*PODO+.00001)+LOG(KTR)+NN*LOG(X+.00001)-X-LNFAC)-KA*A(1)
DADT(2)=KA*A(1)-K*A(2)
$ERROR
IPRED=1
IF (F.GT.0) IPRED=LOG(F)
W=1
IRES=IPRED-DV
IWRES=IRES/W
Y=IPRED+EPS(1)*W
$THETA (0,17.2) ; CL
$THETA (0,45.1) ; V
$THETA (0,.38) ; KA
$THETA (0,.00819) ; COV_CRCL
$THETA (0,2.98) ; COV_KA
$THETA (0,0.37) ; MTT
$THETA (0,20.1) ; NN
$OMEGA 1.11 ; KA
$OMEGA 1.14 ; BIO
$OMEGA 1.52 ; MTT
$OMEGA 0 FIX ; NN
$SIGMA 0.0399 ; RES_ADD
$EST METH=1 INTER MAXEVALS=0 PRINT=2 POSTHOC NOABORT
;$COV
$TABLE ID TIME IPRED IWRES ONEHEADER NOPRINT FILE= sdtab1
$TABLE ID V F1 CL KA MTT   ONEHEADER NOPRINT FILE= patab1
$TABLE ID SEX NYHA PREP    ONEHEADER NOPRINT FILE= catab1
$TABLE ID AGE WT CLCR      ONEHEADER NOPRINT FILE= cotab1