$SIZES NO=1000 LIM6=1000
$PROBLEM
; Markov model for Felodipine GI transit
; Parameterised with mean transit times (MTT)
; Food effect on MTT23 and MTT12
; 4 transit compartments for proximal stomach
; 3 transit compartments for distal stomach

$INPUT STUD OID=DROP ID BAT2=DROP TIME MINU AMT RATE DV1 DV PRS TPRS
       BLQ EVID VAR CMT MDV FOOD GICO AGE=DROP SEX=DROP WT HT=DROP

$DATA Simulated_NMINPUT_D3390M00001_mr_080228x.csv IGNORE=@ IGNORE=(STUD.NE.1)
$SUBROUTINE ADVAN6 TRANS1 TOL=5
$MODEL
 COMP = GI1      ;1 FUNDUS
 COMP = GI2      ;2 ANTRUM
 COMP = GI3_1    ;3 PROXIMAL SMALL INTESTINE
 COMP = GI3_2    ;3 PROXIMAL SMALL INTESTINE
 COMP = GI3_3    ;3 PROXIMAL SMALL INTESTINE
 COMP = GI3_4    ;3 PROXIMAL SMALL INTESTINE
 COMP = GI4_1    ;4 DISTAL SMALL INTESTINE
 COMP = GI4_2    ;4 DISTAL SMALL INTESTINE
 COMP = GI4_3    ;4 DISTAL SMALL INTESTINE
 COMP = GI5      ;5 COLON

$PK
;--- FOOD COVARIATE --------------------------------------
IF(FOOD.EQ.1) THEN
 MTT12 = THETA(6)
 MTT23 = THETA(7) 
ELSE
 MTT12 = THETA(1) * EXP(ETA(1))
 MTT23 = THETA(3)
ENDIF
;---------------------------------------------------------

 MTT21 = THETA(2)
 MTT34 = THETA(4) 
 MTT45 = THETA(5) 

 K12   = 1/(MTT12/60)
 K21   = 1/(MTT21/60)
 K23   = 1/(MTT23/60)
 K34   = 4/(MTT34/60)
 K45   = 3/(MTT45/60)

IF(GICO.LT.3) THEN
 AP3   = 0
 AP4   = 0
 AP5   = 0
 AP6   = 0
 AP7   = 0
 AP8   = 0
 AP9   = 0
ENDIF

 F3   = AP3/(AP3+AP4+AP5+AP6)
 F4   = AP4/(AP3+AP4+AP5+AP6)
 F5   = AP5/(AP3+AP4+AP5+AP6)
 F6   = AP6/(AP3+AP4+AP5+AP6)
 F7   = AP7/(AP7+AP8+AP9)
 F8   = AP8/(AP7+AP8+AP9)
 F9   = AP9/(AP7+AP8+AP9)

$DES
;---------------------------------------------------------
DADT(1)  = K21 * A(2) -K12 * A(1)                   ; 1
DADT(2)  = K12 * A(1) -K21 * A(2) -K23 * A(2)       ; 2
DADT(3)  = K23 * A(2) -K34 * A(3)                   ; 3
DADT(4)  = K34 * A(3) -K34 * A(4)                   ; 3
DADT(5)  = K34 * A(4) -K34 * A(5)                   ; 3
DADT(6)  = K34 * A(5) -K34 * A(6)                   ; 3
DADT(7)  = K34 * A(6) -K45 * A(7)                   ; 4
DADT(8)  = K45 * A(7) -K45 * A(8)                   ; 4
DADT(9)  = K45 * A(8) -K45 * A(9)                   ; 4
DADT(10) = K45 * A(9)                               ; 5
;---------------------------------------------------------

$ERROR

 PG1 = A(1)
 PG2 = A(2)
 P3  = A(3)
 P4  = A(4)
 P5  = A(5)
 P6  = A(6)
 P7  = A(7)
 P8  = A(8)
 P9  = A(9)
 PG5 = A(10)

 PG3 = P3+P4+P5+P6
 PG4 = P7+P8+P9

IF(EVID.EQ.0) THEN
 AP3 = P3
 AP4 = P4
 AP5 = P5
 AP6 = P6 
 AP7 = P7
 AP8 = P8
 AP9 = P9
ELSE
 AP3 = AP3
 AP4 = AP4
 AP5 = AP5
 AP6 = AP6
 AP7 = AP7
 AP8 = AP8
 AP9 = AP9
ENDIF

IF(GICO.EQ.1) Y  = PG1
IF(GICO.EQ.2) Y  = PG2
IF(GICO.EQ.3) Y  = PG3
IF(GICO.EQ.4) Y  = PG4
IF(GICO.EQ.5) Y  = PG5

$THETA  (0,24) ; 1 MTT12fasting
$THETA  (0,165) ; 2 MTT21
$THETA  (0,21.5) ; 3 MTT23fasting
$THETA  (0,130) ; 4 MTT34
$THETA  (0,73.2) ; 5 MTT45
$THETA  (0,62.6) ; 6 MTT12fed
$THETA  (0,222) ; 7 MTT23fed
$OMEGA  0  FIX  ;  1 IIV K12
;--------------------------------------------------------------
$ESTIM PRINT=1 MAX=0 METHOD=COND LIKE LAPLACIAN MSFO=msf100

;$COVARIANCE  PRINT=E

;$TAB ID TIME MINU CMT MDV FOOD PG1 PG2 PG3 PG4 PG5 NOPRINT ONEHEADER FILE=sdtab1
;$TAB ID F3 F4 F5 F6 F7 F8 F9 NOPRINT ONEHEADER FILE=patab1
;$TAB ID TPRS NOPRINT ONEHEADER FILE=cotab1
;$TAB ID PRS FOOD NOPRINT ONEHEADER FILE=catab1